区块链主要开发语言 智能合约使用solidity编程语言开发以太坊应用区块链投票示例

入门知识 6个月前 (02-24) 61次浏览 0个评论

智能合约开发以编程语言部署在以太坊区块链平台上。本文通过官方实战实例快速入门,通过实例深入浅出的讲解智能合约的发展历程,体验以太坊构建去中心化可信交易技术的魅力。智能合约实际上是“执行合约条款的计算机交易协议”。基于区块链的智能合约对区块链上的所有用户都是可见的。

根据维基百科,智能合约(英文:Smart)是一种旨在通知、验证或执行合约的计算机协议。智能合约允许在没有第三方的情况下进行可信交易。这些交易是可追溯且不可逆转的。智能合约的概念由 Nick Szabo 于 1994 年首次提出。智能合约的目的是提供优于传统合约方法的安全性,并降低与合约相关的其他交易成本。

由于区块链上的所有用户都可以看到基于区块链的智能合约。这也使得包括安全漏洞在内的所有漏洞都可见并且可能无法快速修复。这种攻击很难快速解决。

区块链开发_区块链主要开发语言_区块链开发公司哪家好区块链开发

插曲,2016 年 6 月 在开发人员试图达成共识解决方案时,漏洞利用花费了 5000 万美元。在黑客移除资金之前,DAO 的程序有一段时间的延迟。以太坊软件的硬分叉在时限到期之前完成了攻击者资金的回收。以太坊智能合约中的问题包括合约编程、编译器错误、以太坊虚拟机错误、对区块链网络的攻击、程序错误的不变性以及其他尚未记录的攻击。

部署智能合约的经典案例有:

以太坊在其区块链上实现了一种近乎图灵完备的语言,这是一个著名的智能合约框架。(RSK) 是一个通过侧链技术连接到比特币区块链的智能合约平台。RSK 与为以太坊创建的智能合约兼容。

区块链开发公司哪家好区块链开发_区块链开发_区块链主要开发语言

如果你是区块链开发的新手,我建议你看这个教程:以太坊 DApps 入门

典型的智能合约语言编程示例或示例是委托投票系统区块链主要开发语言,如下所示,附注:

官网示例原文:#-

这个例子是最新的,主要使用了以太坊编程语言的一些特性。该示例实现了一个投票智能合约,一个电子投票系统。解决的主要问题是如何给合适的人分配合理的权限,防止他们被篡改。这个例子实现了如何委托投票,整个计票过程是自动的,完全透明的。

功能上,它首先创建一个投票的合约区块链主要开发语言,发起人充当所谓的临时主席,为每个独立的地址分配相应的权限。每个参与者都可以为自己投票或委托给他信任的人。运行此代码的最终结果将返回得票最多的提案或倡议。

pragma solidity ^0.4.22;
/// @title Voting with delegation.一个有委托功能的投票系统
contract Ballot {
    // This declares a new complex type which will 定义一个复杂类型
    // be used for variables later. 后面作为变量来使用
    // It will represent a single voter.代表一个投票人
    struct Voter {
        uint weight; // weight is accumulated by delegation weight在代表投票过程中会累积
        bool voted;  // if true, that person already voted 如果值为true,代表这个投票人已经投过票
        address delegate; // person delegated to 投票人地址
        uint vote;   // index of the voted proposal 当前投票的索引
    }
    // This is a type for a single proposal.代表一份议案的数据结构 
    struct Proposal {
        bytes32 name;   // short name (up to 32 bytes) 议案的名称
        uint voteCount; // number of accumulated votes 议案接受的投票数
    }
    address public chairperson;  // 定义投票发起人
    // This declares a state variable that 
    // stores a `Voter` struct for each possible address. 这个状态变量存储了所有潜在投票人
    mapping(address => Voter) public voters;
    // A dynamically-sized array of `Proposal` structs. 定义动态数组存储议案
    Proposal[] public proposals;
    /// Create a new ballot to choose one of `proposalNames`. 传入议案名称来定义一个投票对象
    function Ballot(bytes32[] proposalNames) public {
        chairperson = msg.sender;
        voters[chairperson].weight = 1;
        // For each of the provided proposal names,
        // create a new proposal object and add it
        // to the end of the array. 按传入的议案名称创建一个议案,并加入到前面定义的议案数组
        for (uint i = 0; i < proposalNames.length; i++) {
            // `Proposal({...})` creates a temporary
            // Proposal object and `proposals.push(...)`
            // appends it to the end of `proposals`.创建一个临时议案对象,加入议案数组
            proposals.push(Proposal({
                name: proposalNames[i],
                voteCount: 0
            }));
        }
    }
    // Give `voter` the right to vote on this ballot.
    // May only be called by `chairperson`. 给投票人分配投票权限,这个操作只有主席才可以
    function giveRightToVote(address voter) public {
        // If the first argument of `require` evaluates
        // to `false`, execution terminates and all
        // changes to the state and to Ether balances
        // are reverted.
        // This used to consume all gas in old EVM versions, but
        // not anymore.
        // It is often a good idea to use `require` to check if
        // functions are called correctly.
        // As a second argument, you can also provide an
        // explanation about what went wrong.
        require(
            msg.sender == chairperson,
            "Only chairperson can give right to vote."
        );
        require(
            !voters[voter].voted,
            "The voter already voted."
        );
        require(voters[voter].weight == 0);
        voters[voter].weight = 1;
    }
    /// Delegate your vote to the voter `to`. 委托投票给另外一个投票人
    function delegate(address to) public {
        // assigns reference 找出委托发起人,如果已经投票,终止程序
        Voter storage sender = voters[msg.sender];
        require(!sender.voted, "You already voted.");
        require(to != msg.sender, "Self-delegation is disallowed.");
        // Forward the delegation as long as
        // `to` also delegated.
        // In general, such loops are very dangerous,
        // because if they run too long, they might
        // need more gas than is available in a block.
        // In this case, the delegation will not be executed,
        // but in other situations, such loops might
        // cause a contract to get "stuck" completely.
        while (voters[to].delegate != address(0)) {
            to = voters[to].delegate;
            // We found a loop in the delegation, not allowed. 发起人、委托人不能是同一个,否则终止程序
            require(to != msg.sender, "Found loop in delegation.");
        }
        // Since `sender` is a reference, this
        // modifies `voters[msg.sender].voted`   标识发起人已经投过票
        sender.voted = true;
        sender.delegate = to;
        Voter storage delegate_ = voters[to];
        if (delegate_.voted) {
            // If the delegate already voted,
            // directly add to the number of votes 投票成功,投票总数加上相应的weight
            proposals[delegate_.vote].voteCount += sender.weight;
        } else {
            // If the delegate did not vote yet,
            // add to her weight. 如果还没投票,发起人weight赋值给委托人
            delegate_.weight += sender.weight;
        }
    }
    /// Give your vote (including votes delegated to you)
    /// to proposal `proposals[proposal].name`.投票给某个议案
    function vote(uint proposal) public {
        Voter storage sender = voters[msg.sender];
        require(!sender.voted, "Already voted.");
        sender.voted = true;
        sender.vote = proposal;
        // If `proposal` is out of the range of the array,
        // this will throw automatically and revert all
        // changes.
        proposals[proposal].voteCount += sender.weight;
    }
    /// @dev Computes the winning proposal taking all
    /// previous votes into account.找出投票数最多的议案
    function winningProposal() public view
            returns (uint winningProposal_)
    {
        uint winningVoteCount = 0;
        for (uint p = 0; p < proposals.length; p++) {
            if (proposals[p].voteCount > winningVoteCount) {
                winningVoteCount = proposals[p].voteCount;
                winningProposal_ = p;
            }
        }
    }
    // Calls winningProposal() function to get the index
    // of the winner contained in the proposals array and then
    // returns the name of the winner
    function winnerName() public view
            returns (bytes32 winnerName_)
    {
        winnerName_ = proposals[winningProposal()].name;
    }
}
复制代码

区块链开发公司哪家好区块链开发_区块链开发_区块链主要开发语言

如果这段代码基本能看懂,应该可以直接开始以太坊区块链的学习过程了。分享两个教程,都可以通过在线编程环境学习:

1.面向区块链新手的以太坊 DApp 开发:

/课程/5a95…

区块链开发_区块链主要开发语言_区块链开发公司哪家好区块链开发

2.用区块链、星际文件系统(IPFS)、Node.js 和 MongoDB 构建以太坊 DApp 电子商务平台:

/课程/5abb…

如果你想加入以太坊技术开发群,可以加微信拉你进群。

挖矿网Ethos中文站简单易用的挖矿系统,为挖矿产业提供教程软件以及矿机测评交易信息等,挖矿网各种数字货币挖矿收益对比计算,挖矿网介绍挖矿的工具,以及矿场的最新消息等。http://www.ethospool.com/

喜欢 (0)
发表我的评论
取消评论
表情 贴图 加粗 删除线 居中 斜体 签到

Hi,您需要填写昵称和邮箱!

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址